Skip to main content

XIAO ESP32S3 Sense 睡眠模式

在这里，我将展示一些简单的示例来演示这些低功耗睡眠模式的使用。所有 ESP32 开发板都是多功能的，我在此上下文中使用的开发板是 XIAO ESP32S3 Sense。

硬件概述​

Seeed Studio XIAO ESP32S3 Sense
立即获取 🖱️

深度睡眠​

介绍​

在深度睡眠模式下，ESP32 会关闭 CPU、大部分 RAM 和所有由 APB_CLK 时钟驱动的数字外设。唯一保持供电的组件是：

  • RTC 控制器
  • ULP 协处理器
  • RTC FAST 内存
  • RTC SLOW 内存

唤醒方法​

  • **定时器唤醒：**ESP32 可以通过设置定时器在指定时间后自动唤醒。

  • **触摸板中断唤醒：**设备可以通过触摸板活动唤醒，适用于需要用户交互的应用。

  • **外部唤醒：**ESP32 可以通过外部信号（例如按钮按下）唤醒，非常适合低功耗应用。

  • **ULP 协处理器活动唤醒：**ULP 协处理器可以独立运行，监控特定条件并唤醒主 CPU 以节省功耗。

  • **GPIO 唤醒：**设备可以通过 GPIO 引脚状态变化（高电平或低电平）唤醒，为各种传感器和外设提供灵活性。

下面给出了 XIAO ESP32 S3 Sense 使用深度睡眠模式的三个简单示例。

代码实现​


#define uS_TO_S_FACTOR 1000000ULL 
#define TIME_TO_SLEEP  5       

RTC_DATA_ATTR int bootCount = 0;

void print_wakeup_reason() {
  esp_sleep_wakeup_cause_t wakeup_reason;

  wakeup_reason = esp_sleep_get_wakeup_cause();

  switch (wakeup_reason) {
    case ESP_SLEEP_WAKEUP_EXT0:     Serial.println("Wakeup caused by external signal using RTC_IO"); break;
    case ESP_SLEEP_WAKEUP_EXT1:     Serial.println("Wakeup caused by external signal using RTC_CNTL"); break;
    case ESP_SLEEP_WAKEUP_TIMER:    Serial.println("Wakeup caused by timer"); break;
    case ESP_SLEEP_WAKEUP_TOUCHPAD: Serial.println("Wakeup caused by touchpad"); break;
    case ESP_SLEEP_WAKEUP_ULP:      Serial.println("Wakeup caused by ULP program"); break;
    default:                        Serial.printf("Wakeup was not caused by deep sleep: %d\n", wakeup_reason); break;
  }
}

void setup() {
  Serial.begin(115200);
  delay(1000);  


  ++bootCount;
  Serial.println("Boot number: " + String(bootCount));


  print_wakeup_reason();


  esp_sleep_enable_timer_wakeup(TIME_TO_SLEEP * uS_TO_S_FACTOR);
  Serial.println("Setup ESP32 to sleep for every " + String(TIME_TO_SLEEP) + " Seconds");

  Serial.println("Going to sleep now");
  Serial.flush();
  esp_deep_sleep_start();
  Serial.println("This will never be printed");
}

void loop() {

}

详细说明​

#define uS_TO_S_FACTOR 1000000ULL
  • 定义一个宏来将微秒转换为秒。1000000ULL 是用于将微秒转换为秒的因子。
#define TIME_TO_SLEEP  5
  • 定义一个宏，设置ESP32进入睡眠的时间，在这种情况下是5秒。
RTC_DATA_ATTR int bootCount = 0;
  • 声明一个整型变量 bootCount，带有 RTC_DATA_ATTR 属性，这允许它在深度睡眠期间保持其值。
void print_wakeup_reason() {
  • 定义一个名为 print_wakeup_reason() 的函数，该函数将打印 ESP32 唤醒的原因。
esp_sleep_wakeup_cause_t wakeup_reason;
  • 声明一个类型为 esp_sleep_wakeup_cause_t 的变量 wakeup_reason 来存储唤醒事件的原因。
wakeup_reason = esp_sleep_get_wakeup_cause();
  • 调用函数 esp_sleep_get_wakeup_cause() 来获取唤醒原因并将其赋值给 wakeup_reason 变量。
  switch (wakeup_reason) {
    case ESP_SLEEP_WAKEUP_EXT0:     Serial.println("Wakeup caused by external signal using RTC_IO"); break;
    case ESP_SLEEP_WAKEUP_EXT1:     Serial.println("Wakeup caused by external signal using RTC_CNTL"); break;
    case ESP_SLEEP_WAKEUP_TIMER:    Serial.println("Wakeup caused by timer"); break;
    case ESP_SLEEP_WAKEUP_TOUCHPAD: Serial.println("Wakeup caused by touchpad"); break;
    case ESP_SLEEP_WAKEUP_ULP:      Serial.println("Wakeup caused by ULP program"); break;
    default:                        Serial.printf("Wakeup was not caused by deep sleep: %d\n", wakeup_reason); break;
}
  • ESP_SLEEP_WAKEUP_EXT0 : 此唤醒原因表示ESP32由于在配置为RTC（实时时钟）I/O的GPIO引脚上检测到外部信号而唤醒。这通常用于当按钮或传感器被触发时从睡眠中唤醒。
  • ESP_SLEEP_WAKEUP_EXT1 : 这表示唤醒是由RTC控制器管理的GPIO引脚上的外部信号引起的。与EXT0不同，EXT1可以处理多个引脚，并且可以在任何指定引脚改变状态时唤醒（例如，变为低电平或高电平）。
  • ESP_SLEEP_WAKEUP_TIMER : 此唤醒原因表示ESP32在预定义的定时器持续时间后唤醒。这对于需要执行周期性任务而不需要用户交互的应用程序很有用。
  • ESP_SLEEP_WAKEUP_TOUCHPAD : 这表示ESP32由于触摸板事件而唤醒。如果配置为唤醒的触摸板检测到触摸，它可以使设备退出睡眠模式。
  • ESP_SLEEP_WAKEUP_ULP : 此唤醒原因意味着唤醒是由ULP（超低功耗）程序触发的。ULP可以在主CPU处于深度睡眠时运行，并且可以在满足某些条件时唤醒ESP32，从而实现低功耗操作，最大限度地减少电池消耗。
++bootCount;
  • 每次设备重启时递增启动计数并打印。
print_wakeup_reason();
  • 打印ESP32唤醒的原因。
esp_sleep_enable_timer_wakeup(TIME_TO_SLEEP * uS_TO_S_FACTOR);
Serial.println("Setup ESP32 to sleep for every " + String(TIME_TO_SLEEP) + " Seconds");

Serial.println("Going to sleep now");
Serial.flush();
esp_deep_sleep_start();
Serial.println("This will never be printed");
  • esp_sleep_enable_timer_wakeup(TIME_TO_SLEEP * uS_TO_S_FACTOR);启用定时器在指定时间后唤醒ESP32。
  • Serial.flush();确保所有串口数据在进入睡眠前发送完毕。
  • esp_deep_sleep_start();将ESP32置于深度睡眠模式。
tip

要在进入深度睡眠模式后重新烧录程序，请按住启动按钮，然后按下复位按钮来重启ESP32。

结果展示​

轻度睡眠​

介绍​

轻度睡眠模式是ESP32中的另一种低功耗模式，允许设备在节约能源的同时仍保持快速响应时间。在此模式下，CPU内核被暂停，但RAM和一些外设保持供电，使设备能够快速响应某些事件而唤醒。

轻度睡眠非常适合需要低功耗但仍需要保持WiFi或蓝牙连接的应用，因为它允许无线通信模块保持活跃状态。

唤醒方法​

  • 定时器唤醒： 设备可以在指定时间段后唤醒，允许执行周期性任务。
  • 外部中断唤醒： ESP32可以通过外部信号唤醒，如按钮按压或其他硬件中断。
  • 网络活动唤醒： 设备可以响应传入的网络数据包而唤醒，实现高效通信而无需持续处于活跃状态。
  • GPIO唤醒： 可以配置特定的GPIO引脚在发生事件时唤醒设备，如状态变化或信号变化。

代码实现​

#include <freertos/FreeRTOS.h>
#include <freertos/task.h>

const int sleepTime = 10000;
const int ledPin = LED_BUILTIN; 

void ledTask(void *pvParameters) {
  digitalWrite(ledPin, HIGH);
  Serial.println("LED is ON");
  vTaskDelay(pdMS_TO_TICKS(1000));
  digitalWrite(ledPin, LOW);
  Serial.println("LED is OFF");
  
  vTaskDelete(NULL); 
}

void setup() {
  Serial.begin(115200);
  pinMode(ledPin, OUTPUT);
  Serial.println("Setup complete. Going to sleep...");
}

void loop() {
  esp_sleep_enable_timer_wakeup(sleepTime * 1000);
  Serial.println("Going to sleep now...");
  esp_light_sleep_start();

  xTaskCreate(ledTask, "LED Task", 2048, NULL, 1, NULL);
  
  delay(1000);
}

详细说明​

#include <freertos/FreeRTOS.h>
#include <freertos/task.h>
  • 包含 FreeRTOS 库
const int sleepTime = 10000; 
const int ledPin = LED_BUILTIN;
  • 设置睡眠时间为10秒
  • 使用内置LED引脚
void ledTask(void *pvParameters):
  • 定义一个 FreeRTOS 任务来控制 LED 状态。
digitalWrite(ledPin, HIGH); 
Serial.println("LED is ON"); 
vTaskDelay(pdMS_TO_TICKS(1000)); 
digitalWrite(ledPin, LOW);
Serial.println("LED is OFF"); 
vTaskDelete(NULL);
  • vTaskDelay(pdMS_TO_TICKS(1000)); 保持LED亮1秒
  • vTaskDelete(NULL); 删除当前任务
esp_sleep_enable_timer_wakeup(sleepTime * 1000);
Serial.println("Going to sleep now..."); 
esp_light_sleep_start(); 
xTaskCreate(ledTask, "LED Task", 2048, NULL, 1, NULL); 
delay(1000);
  • esp_sleep_enable_timer_wakeup(sleepTime * 1000);设置唤醒定时器
  • esp_light_sleep_start(); 进入浅睡眠模式
  • xTaskCreate(ledTask, "LED Task", 2048, NULL, 1, NULL);创建LED控制任务

结果展示​

Modem-Sleep​

介绍​

Modem Sleep模式是ESP32中另一个重要的低功耗模式，它与Deep Sleep模式不同。Modem Sleep模式主要针对ESP32的无线通信模块进行优化。

在此模式下，ESP32的WiFi/蓝牙模块进入睡眠状态，而CPU核心保持活跃。这使得ESP32能够在显著降低功耗的同时保持一定程度的无线连接能力。

唤醒方式​

  • 定时器唤醒

  • 外部中断唤醒

  • 任务唤醒

  • 网络活动唤醒

代码实现​

#include "WiFi.h"

void setup() {
    Serial.begin(115200);
    Serial.println("Connecting to WiFi...");

    WiFi.begin("****", "****");

    while (WiFi.status() != WL_CONNECTED) {
        delay(1000);
        Serial.println("Connecting...");
    }
    Serial.println("Connected to WiFi!");
 
    WiFi.setSleep(true); 
    Serial.println("Modem-Sleep enabled.");
}

void loop() {

    Serial.println("Running...");

    delay(5000);

    WiFi.setSleep(false); 
    Serial.println("Modem-Sleep disabled. WiFi is active.");

    if (WiFi.status() == WL_CONNECTED) {
        Serial.println("Still connected to WiFi.");
    } else {
        Serial.println("WiFi disconnected.");
    }

    delay(5000);
    WiFi.setSleep(true); 
    Serial.println("Modem-Sleep enabled.");
}

详细说明​

#include "WiFi.h"
  • 包含WiFi库以启用WiFi功能。
Serial.println("Connecting to WiFi...");
  • 打印一条消息，表示正在开始连接到WiFi。
WiFi.begin("****", "****");
  • 开始连接到指定的WiFi网络。
    while (WiFi.status() != WL_CONNECTED) {
        delay(1000);
        Serial.println("Connecting...");
    }
    Serial.println("Connected to WiFi!");
  • 循环直到成功连接到WiFi。
WiFi.setSleep(true);
  • 启用调制解调器睡眠模式以节省电力。
WiFi.setSleep(false);
  • 禁用调制解调器睡眠模式以激活WiFi。
if (WiFi.status() == WL_CONNECTED) {
  • 检查WiFi状态。
WiFi.setSleep(true);
  • 重新启用调制解调器睡眠模式。

结果展示​

睡眠功能应用​

通过上面的简单示例，现在让我们更进一步，在 ESP32 S3 Sense 传感器上使用这些睡眠功能。

软件准备​

在开始本文之前，如果您还没有利用 XIAO ESP32S3 Sense 上的所有硬件功能，请确保您已经完成了一些软件安装准备工作。

以下是三个功能的介绍，您可以通过以下链接找到更多信息：

  • 麦克风使用：学习如何使用 XIAO ESP32S3 Sense 上的麦克风来捕获环境声音级别并录制音频。

  • MicroSD：了解如何使用 MicroSD 卡进行数据存储，确保您可以在项目中保存和检索文件。

  • 相机使用：掌握如何使用 XIAO ESP32S3 Sense 上的相机模块拍照和录制视频。

代码实现​

#include "esp_camera.h"
#include "FS.h"
#include "SD.h"
#include "SPI.h"

#define CAMERA_MODEL_XIAO_ESP32S3 

#include "camera_pins.h"

unsigned long lastCaptureTime = 0; 
int imageCount = 1;                
bool camera_sign = false;        // 摄像头标志
bool sd_sign = false;             // SD卡标志


void photo_save(const char * fileName) {
  camera_fb_t *fb = esp_camera_fb_get();
  if (!fb) {
    Serial.println("获取摄像头帧缓冲区失败");
    return;
  }
  writeFile(SD, fileName, fb->buf, fb->len);
  
  esp_camera_fb_return(fb);

  Serial.println("照片已保存到文件");
}

void writeFile(fs::FS &fs, const char * path, uint8_t * data, size_t len){
    Serial.printf("写入文件: %s\r\n", path);

    File file = fs.open(path, FILE_WRITE);
    if (!file) {
        Serial.println("打开文件进行写入失败");
        return;
    }
    if (file.write(data, len) == len) {
        Serial.println("文件已写入");
    } else {
        Serial.println("写入失败");
    }
    file.close();
}

void setup() {
  Serial.begin(115200);
  while (!Serial); 

  camera_config_t config;
  config.ledc_channel = LEDC_CHANNEL_0;
  config.ledc_timer = LEDC_TIMER_0;
  config.pin_d0 = Y2_GPIO_NUM;
  config.pin_d1 = Y3_GPIO_NUM;
  config.pin_d2 = Y4_GPIO_NUM;
  config.pin_d3 = Y5_GPIO_NUM;
  config.pin_d4 = Y6_GPIO_NUM;
  config.pin_d5 = Y7_GPIO_NUM;
  config.pin_d6 = Y8_GPIO_NUM;
  config.pin_d7 = Y9_GPIO_NUM;
  config.pin_xclk = XCLK_GPIO_NUM;
  config.pin_pclk = PCLK_GPIO_NUM;
  config.pin_vsync = VSYNC_GPIO_NUM;
  config.pin_href = HREF_GPIO_NUM;
  config.pin_sscb_sda = SIOD_GPIO_NUM;
  config.pin_sscb_scl = SIOC_GPIO_NUM;
  config.pin_pwdn = PWDN_GPIO_NUM;
  config.pin_reset = RESET_GPIO_NUM;
  config.xclk_freq_hz = 20000000;
  config.frame_size = FRAMESIZE_UXGA;
  config.pixel_format = PIXFORMAT_JPEG; 
  config.grab_mode = CAMERA_GRAB_WHEN_EMPTY;
  config.fb_location = CAMERA_FB_IN_PSRAM;
  config.jpeg_quality = 12;
  config.fb_count = 1;

  esp_err_t err = esp_camera_init(&config);
  if (err != ESP_OK) {
    Serial.printf("摄像头初始化失败，错误代码 0x%x", err);
    return;
  }

  camera_sign = true; 

  if (!SD.begin(21)) {
    Serial.println("SD卡挂载失败");
    return;
  }
  
  uint8_t cardType = SD.cardType();
  
  if (cardType == CARD_NONE) {
    Serial.println("未连接SD卡");
    return;
  }

  Serial.print("SD卡类型: ");
  if (cardType == CARD_MMC) {
    Serial.println("MMC");
  } else if (cardType == CARD_SD) {
    Serial.println("SDSC");
  } else if (cardType == CARD_SDHC) {
    Serial.println("SDHC");
  } else {
    Serial.println("未知");
  }

  sd_sign = true; 

  Serial.println("照片拍摄即将开始，请做好准备。");
}

void loop() {
  if (camera_sign && sd_sign) {
    unsigned long now = millis();
  
    if ((now - lastCaptureTime) >= 60000) {
      char filename[32];
      sprintf(filename, "/image%d.jpg", imageCount);
      photo_save(filename);
      Serial.printf("已保存照片: %s\r\n", filename);
      Serial.println("进入深度睡眠10秒...");
      
      esp_sleep_enable_timer_wakeup(10000000); 
      esp_deep_sleep_start(); 
      
    }
  }
}

详细说明​

这段代码实现了一个基于ESP32摄像头模块的图像捕获系统，可以每60秒自动拍摄一张照片并保存到SD卡中。在void setup()函数中，初始化摄像头和SD卡并确认设备状态；在void loop()函数中，检查摄像头是否可以拍照，如果满足条件，则调用photo_save()函数保存图像，保存后进入深度睡眠状态10秒以节省能耗。

tip

这些代码不能直接使用，您需要添加关于摄像头的头文件，请查看上面关于 XIAO ESP32 S3 的示例。

总结​

为什么使用深度睡眠模式​

在不影响功能的情况下最大化节能，以延长设备的电池寿命。 适用场景：电池寿命至关重要的应用，如远程传感器节点、可穿戴设备和其他低功耗物联网设备。虽然唤醒时间相对较慢，但这种权衡是值得的。

为什么使用调制解调器睡眠模式​

优化无线通信模块的功耗，同时仍保持网络连接。 适用场景：需要保持网络连接但也需要低功耗的应用，如间歇工作的物联网设备。调制解调器睡眠可以显著降低无线模块的功耗，同时仍提供快速唤醒响应。

总结​

这三种睡眠模式为开发者提供了不同的功耗/性能权衡选项，可以根据应用的具体要求灵活选择。对于有电池寿命要求的设备，深度睡眠模式是一个好选择；而对于需要保持网络连接的物联网设备，调制解调器睡眠模式是最佳选择。

技术支持与产品讨论​

感谢您选择我们的产品！我们在这里为您提供不同的支持，以确保您使用我们产品的体验尽可能顺畅。我们提供多种沟通渠道，以满足不同的偏好和需求。

Loading Comments...