Skip to main content

Blynkへの接続

note

この文書は AI によって翻訳されています。内容に不正確な点や改善すべき点がございましたら、文書下部のコメント欄または以下の Issue ページにてご報告ください。
https://github.com/Seeed-Studio/wiki-documents/issues

Wio Terminal をBlynkに接続する

このWikiでは、Wio TerminalをBlynkソフトウェアと連携させてWi-FiまたはBluetoothを使用する方法を紹介します。これにより、Wio TerminalをIoTデバイスのコアとして使用し、スマートフォンからハードウェアを非常に簡単に制御できるようになります！

  • Blynkとは

Blynkは、iOSおよびAndroidデバイスからハードウェアプロジェクトを制御および監視するためのインターフェースを迅速に構築できる新しいプラットフォームです。Blynkアプリをダウンロードした後、プロジェクトダッシュボードを作成し、ボタン、スライダー、グラフ、その他のウィジェットを画面上に配置できます。

必要なハードウェア​

  • Wio Terminal

  • スマートフォン

    • App StoreからBlynkアプリをダウンロード

はじめに​

blynk-libraryのインストール​

  1. blynk-libraryのリポジトリにアクセスし、リポジトリ全体をローカルドライブにダウンロードします。

  2. 次に、このライブラリをArduino IDEにインストールします。Arduino IDEを開き、スケッチ -> ライブラリをインクルード -> ZIP形式のライブラリを追加をクリックし、先ほどダウンロードしたblynk-libraryファイルを選択します。

InstallLibrary

Wi-Fiの依存関係​

現在、Wi-FiとBluetoothは別々のファームウェアであり、同時に使用することはできません。

注意: Wi-FiとBluetoothが同時に動作する新しいファームウェアは開発中で、近日中にリリースされる予定です。

  • Wi-Fi Overview Wikiに従って、Wi-FiファームウェアをWio Terminalにアップロードしてください。

  • また、すべての依存Wi-Fiライブラリをダウンロードしてインストールしてください。

Bluetoothの依存関係​

  • Bluetooth Overview Wikiに従って、BluetoothファームウェアをWio Terminalにアップロードしてください。

  • また、すべての依存Bluetoothライブラリをダウンロードしてインストールしてください。

Blynkモバイルアプリのセットアップ​

Blynkアプリをダウンロードしたら：

  • アプリを開きます。

  • 新しいプロジェクトをクリックします：

  • プロジェクト名を入力し、デバイスとしてArduino UNOを選択し、接続タイプとしてWiFiまたはBluetoothを選択します。その後、プロジェクトを作成をクリックします：
  • 次に、Blynkに登録したメールアドレスにトークンが送信されます。これは後でArduinoスケッチで必要になります。

Wi-Fiの例​

これらの例では、Wio TerminalとBlynkアプリ間でWi-Fiを使用して通信します。

シンプルなWi-Fi接続​

この例では、特定のWi-Fiに接続し、その後Blynkサーバーに接続します。

  • トークンをメールで受け取ったものに置き換えて、authに設定してください。

  • ネットワークのSSIDとPasswordを置き換えてください。

  • スケッチをWio Terminalにアップロードしてください。

#define BLYNK_PRINT Serial

#include <rpcWiFi.h>
#include <WiFiClient.h>
#include <BlynkSimpleWioTerminal.h>

// BlynkアプリでAuth Tokenを取得してください。
// プロジェクト設定（ナットアイコン）に移動します。
char auth[] = "YourToken";

// WiFiの認証情報。
// オープンネットワークの場合はパスワードを""に設定します。
char ssid[] = "SSID";
char pass[] = "Password";

void setup()
{
  // デバッグコンソール
  Serial.begin(9600);

  Blynk.begin(auth, ssid, pass);
}

void loop()
{
  Blynk.run();
}

アップロード後、スマートフォンでBlynkアプリを開き、右上の再生ボタンをクリックしてライブにします。接続されていることが確認できるはずです！

温度をBlynkに送信する​

この例では、Wio TerminalからBlynkサーバーにデータを送信し、そのデータをモバイルアプリで表示する方法を示します。

  • WiFiの認証情報とトークンを置き換えてください。

  • 温度データは仮想ピン0（V0）に送信されます。

  • Wio Terminalにアップロードしてください。

note
この例では、温度値はランダムに生成されます。
#define BLYNK_PRINT Serial

#include <rpcWiFi.h>
#include <WiFiClient.h>
#include <BlynkSimpleWioTerminal.h>

// WiFiの認証情報。
const char* ssid = "SSID";
const char* pass = "Password";

// BlynkアプリでAuth Tokenを取得してください。
// プロジェクト設定（ナットアイコン）に移動します。
char auth[] = "YourToken";

BlynkTimer timer;

void sendTemperature() {
  // ランダムな温度値を生成（例：10.0〜30.0）
  float t = float(random(100, 300)) / 10;
  // フォーマット：小数点1桁、℃を追加
  String str = String(t, 1) + "℃";
  // サーバーに送信
  Blynk.virtualWrite(V0, str);
}

void setup() {
  // デバッグコンソール
  Serial.begin(9600);

  Blynk.begin(auth, ssid, pass);
  timer.setInterval(1000L, sendTemperature);
}

void loop() {
  Blynk.run();
  timer.run();
}

再びスマートフォンでBlynkアプリを開きます。

  • 左にスワイプしてウィジェットボックスを表示し、Value Displayを選択します：
  • ボタンをクリックし、仮想ピン0に割り当てるように設定します：
  • 設定を保存し、右上の再生ボタンをクリックしてライブにします！スマートフォンで温度値が表示されるのが確認できます。

Bluetoothの例​

これらの例では、Wio TerminalとBlynkアプリ間でBluetoothを使用して通信します。

シンプルなBluetooth接続​

この例では、Wio TerminalのBluetoothを使用してモバイルフォンのBluetoothに接続します。

  • トークンをauthに置き換えてください。

  • Wio Terminalにアップロードしてください。

#define BLYNK_PRINT Serial
#define BLYNK_USE_DIRECT_CONNECT

#include <BlynkSimpleWioTerminal_BLE.h>
#include <BLEDevice.h>
#include <BLEServer.h>

// BlynkアプリでAuth Tokenを取得してください。
// プロジェクト設定（ナットアイコン）に移動します。
char auth[] = "YourToken";

void setup()
{
  // デバッグコンソール
  Serial.begin(9600);
  Serial.println("接続を待っています...");
  Blynk.setDeviceName("Blynk");
  Blynk.begin(auth);
}

void loop()
{
  Blynk.run();
}

次に、Blynkアプリを開き、以下のように設定します：

  • 左にスワイプしてウィジェットボックスを表示し、BLEウィジェットを見つけます：
  • BLEウィジェットをクリックし、Blynkという名前のBLEデバイスに接続します：
  • BLEが接続されたら、再生ボタンをクリックしてライブにします！

これで、Wio TerminalがBluetoothを使用してBlynkに接続されました！

Blynkを使用したRGBストリップの制御​

この例では、RGBストリップをWio Terminalに接続し、Blynkを使用して表示する色を制御します！

Adafruit_NeoPixelライブラリのインストール​

  1. Adafruit_NeoPixelリポジトリを訪問し、リポジトリ全体をローカルドライブにダウンロードします。

  2. 次に、Arduino IDEにライブラリをインストールします。Arduino IDEを開き、スケッチ -> ライブラリをインクルード -> ZIP形式のライブラリを追加をクリックし、先ほどダウンロードしたAdafruit_NeoPixelファイルを選択します。

  • 環境に応じてPINとNUMPIXELSを設定してください。
  • RGB値はBlynkアプリから読み取り、仮想ピン2（V2）に割り当てられます。
  • Wio Terminalにアップロードしてください。
#define BLYNK_PRINT Serial
#define BLYNK_USE_DIRECT_CONNECT

#include <BlynkSimpleWioTerminal_BLE.h>
#include <BLEDevice.h>
#include <BLEServer.h>
#include <Adafruit_NeoPixel.h>

#include <TFT_eSPI.h> // ハードウェア固有のライブラリ
TFT_eSPI tft = TFT_eSPI();       // カスタムライブラリを呼び出し

#define PIN 0
#define NUMPIXELS 20
#define BLYNK_PRINT Serial
Adafruit_NeoPixel pixels(NUMPIXELS, PIN, NEO_GRB + NEO_KHZ800);

// BlynkアプリでAuth Tokenを取得してください。
// プロジェクト設定（ナットアイコン）に移動します。
char auth[] = "YourToken";

BLYNK_WRITE(V2)
{
  int R = param[0].asInt();
  int G = param[1].asInt();
  int B = param[2].asInt();
  tft.fillScreen(tft.color565(R, G, B));
  for (int i = 0; i < NUMPIXELS; i++) {
    pixels.setPixelColor(i, pixels.Color(R, G, B));
    pixels.show();
  }
}

void setup() {
  // デバッグコンソール
  Serial.begin(9600);
  Serial.println("接続を待っています...");
  Blynk.setDeviceName("Blynk");

  Blynk.begin(auth);
  
  tft.begin();
  tft.fillScreen(TFT_BLACK);
  pixels.begin();
}

void loop() {
  Blynk.run();
}

Blynkアプリを開き、以下のように設定してください：

  • 左にスワイプしてウィジェットボックスを表示し、下にスクロールしてzeRGBaウィジェットを見つけます：
  • zeRGBaウィジェットをクリックし、以下のように設定します。出力をMergeに設定し、Virtual Pin 2 (V2)に割り当て、値の範囲を0から255に設定します。
  • 最初にBLEウィジェットが接続されていることを確認し、再生ボタンをクリックしてライブモードにします！Blynk上で色をドラッグするだけで、LEDストリップのRGBカラーを簡単に変更できます。

技術サポートと製品ディスカッション​

弊社の製品をお選びいただきありがとうございます！お客様が弊社の製品をスムーズにご利用いただけるよう、さまざまなサポートをご提供しています。異なるニーズやご希望に応じた複数のコミュニケーションチャネルをご用意しています。

Loading Comments...