Seeed Studio XIAO MG24 Exemplo - Matter

Introdução

Matter é um padrão unificado e de código aberto para tecnologia de casa inteligente que promove a interoperabilidade entre dispositivos e ecossistemas. Desenvolvido pela Connectivity Standards Alliance (CSA), ele permite comunicação perfeita entre dispositivos de vários fabricantes sem exigir conectividade com a internet. Matter oferece compatibilidade nativa com plataformas como Apple HomeKit, Google Home e Amazon Alexa, facilitando a integração de dispositivos em configurações de casa inteligente. Para um entendimento mais profundo sobre Matter, consulte a documentação oficial do Matter.

Em 2024¹, a Silicon Labs e a Arduino uniram forças para reduzir as barreiras de adoção do Matter, fornecendo um caminho de desenvolvimento que simplifica o uso de Matter com o ecossistema Arduino. Essa colaboração tem como objetivo tornar o desenvolvimento com Matter mais acessível, ajudando desenvolvedores Arduino a superar desafios típicos e adotar Matter sem dificuldades.

Matter opera de forma eficiente em redes locais, oferecendo comunicação confiável e de baixa latência sem necessidade de acesso à internet. Esse recurso melhora significativamente tanto a segurança quanto o desempenho dos dispositivos.

Esta documentação o guiará pelos passos para desenvolver um aplicativo Matter no XIAO MG24 usando Arduino.

Pré-requisitos

Para começar a desenvolver um aplicativo Matter no XIAO MG24, certifique-se de que os seguintes componentes de hardware e software estejam preparados e prontos.

Hardware

• Placa Seeed Studio XIAO MG24.
• Hub Matter compatível (por exemplo, Apple HomePod mini) para se conectar à rede Matter.
• Controlador Matter (por exemplo, app Apple HomeKit) para gerenciar e interagir com o seu dispositivo compatível com Matter.

A tabela a seguir² fornece exemplos de hubs compatíveis com Matter em vários ecossistemas:

Fabricante / Ecossistema	Dispositivo
Google Home	Nest Hub Gen2
Apple HomeKit	HomePod Gen2, HomePod mini
Amazon Alexa	Echo Gen4
Raspberry Pi OTBR	Raspberry Pi

Por padrão, presume-se que você tenha pelo menos um Matter Hub e um Matter Controller (por exemplo, um iPhone com HomeKit instalado) prontos para teste.

Software

O software necessário inclui a IDE Arduino com o Arduino Core da Silicon Labs:

• Se ainda não estiver instalado, baixe e configure o Silicon Labs Arduino Core para compatibilidade com o XIAO MG24.
• Para instruções detalhadas de configuração, consulte o Guia de Primeiros Passos.

Certifique-se de optar pela pilha do protocolo Matter:

Início Rápido com o Exemplo de Lâmpada Matter

O Exemplo de Lâmpada Matter demonstra um aplicativo Matter simples, permitindo o controle do built-in LED via uma rede Matter. Este exemplo serve como um ponto de partida prático para desenvolvedores iniciantes na integração do Matter no XIAO MG24.

Para acessar o exemplo na IDE Arduino:

Para conveniência, são fornecidas abaixo modificações no nome do dispositivo no código de exemplo para permitir uma configuração personalizada.

/*
   Matter lightbulb example

   The example shows how to create a simple on/off lightbulb with the Arduino Matter API.

   The example lets users control the onboard LED through Matter.
   The device has to be commissioned to a Matter hub first.

   Author: Tamas Jozsi (Silicon Labs)
   Modified by: Spencer Y (Seeed Studio)
 */
#include <Matter.h>
#include <MatterLightbulb.h>

MatterLightbulb matter_bulb;

void setup()
{
  Serial.begin(115200);
  Matter.begin();
  matter_bulb.begin();

  pinMode(LED_BUILTIN, OUTPUT);
  digitalWrite(LED_BUILTIN, LED_BUILTIN_INACTIVE);

  Serial.println("Matter lightbulb");

  matter_bulb.set_device_name("XIAO MG24 bulb");    // Customize the default device name
  matter_bulb.set_vendor_name("Seeed Studio");      // Set the vendor name
  matter_bulb.set_product_name("Seeed Matter Lightbulb"); // Define the product name

  if (!Matter.isDeviceCommissioned()) {
    Serial.println("Matter device is not commissioned");
    Serial.println("Commission it to your Matter hub with the manual pairing code or QR code");
    Serial.printf("Manual pairing code: %s\n", Matter.getManualPairingCode().c_str());
    Serial.printf("QR code URL: %s\n", Matter.getOnboardingQRCodeUrl().c_str());
  }
  while (!Matter.isDeviceCommissioned()) {
    delay(200);
  }

  Serial.println("Waiting for Thread network...");
  while (!Matter.isDeviceThreadConnected()) {
    delay(200);
  }
  Serial.println("Connected to Thread network");

  Serial.println("Waiting for Matter device discovery...");
  while (!matter_bulb.is_online()) {
    delay(200);
  }
  Serial.println("Matter device is now online");
}

void loop()
{
  static bool matter_lightbulb_last_state = false;
  bool matter_lightbulb_current_state = matter_bulb.get_onoff();

  // Turn on the LED if the state is ON and the previous state was OFF
  if (matter_lightbulb_current_state && !matter_lightbulb_last_state) {
    matter_lightbulb_last_state = matter_lightbulb_current_state;
    digitalWrite(LED_BUILTIN, LED_BUILTIN_ACTIVE);
    Serial.println("Bulb ON");
  }

  // Turn off the LED if the state is OFF and the previous state was ON
  if (!matter_lightbulb_current_state && matter_lightbulb_last_state) {
    matter_lightbulb_last_state = matter_lightbulb_current_state;
    digitalWrite(LED_BUILTIN, LED_BUILTIN_INACTIVE);
    Serial.println("Bulb OFF");
  }
}

Gravação do Firmware

1. Copie o código para a IDE Arduino e faça o upload para a placa XIAO MG24.

2. Após gravar o firmware, pressione o botão RESET ou reconecte o XIAO MG24 para reiniciar a placa.
3. Abra o Serial Monitor para confirmar a configuração. Você deverá ver uma saída semelhante a esta:

QR Code para Comissionamento

O Serial Monitor exibirá uma URL para gerar um QR code, necessário para o comissionamento do dispositivo. Copie a URL, cole-a em um navegador e escaneie o QR code resultante com o seu controlador Matter (por exemplo, HomeKit).

Testando o Dispositivo

Após escanear o QR code, o controlador Matter (HomeKit) solicitará que você confirme a identidade do dispositivo. Uma vez confirmada, o dispositivo ficará visível no app. Agora você pode controlar o LED integrado do XIAO MG24 e testar sua resposta diretamente pela interface do aplicativo.

Referências & Recursos

Se você é novo em Matter, os recursos a seguir fornecem conhecimento fundamental e suporte de desenvolvimento para trabalhar dentro do ecossistema Matter:

• Guias de Início Rápido: Um ponto de partida ideal para aprender os fundamentos de Matter, cobrindo conceitos essenciais e componentes do ecossistema.
• Matter Developer Journey: Um guia abrangente pelo processo de desenvolvimento com Matter, incluindo ferramentas necessárias, recursos e boas práticas para uma implementação eficaz.
• Especificações do Matter: Especificações técnicas para o protocolo Matter e seus componentes. Este é o recurso principal para entender as capacidades e detalhes de operação do protocolo.
• The Device Data Model - Google Home Developers: Uma explicação detalhada do modelo de dados do dispositivo, que padroniza como os recursos e capacidades dos dispositivos são representados no ecossistema Matter.
• Visão Geral do Framework de Desenvolvimento Matter: Um guia especificamente voltado para o Matter Development Framework para o XIAO ESP32C6, oferecendo uma abordagem alternativa para o desenvolvimento de dispositivos Matter.

Suporte Técnico & Discussão de Produto

Obrigado por escolher nossos produtos! Estamos aqui para oferecer diferentes tipos de suporte e garantir que sua experiência com nossos produtos seja a mais tranquila possível. Oferecemos vários canais de comunicação para atender a diferentes preferências e necessidades.

Footnotes

1. Silicon Labs and Arduino Partner to Democratize Matter - Feb 6, 2024 ↩

2. README - Arduino Matter library ↩